winforms Getting started with winforms Creating a Simple VB.NET WinForms Application using a Text Editor

Example

1. Open a text editor (like Notepad), and type the code below:

    Imports System.ComponentModel
    Imports System.Drawing
    Imports System.Windows.Forms
   
    Namespace SampleApp
        Public Class MainForm : Inherits Form
            Private btnHello As Button
    
            ' The form's constructor: this initializes the form and its controls.
            Public Sub New()
                ' Set the form's caption, which will appear in the title bar.
                Me.Text = "MainForm"
    
                ' Create a button control and set its properties.
                btnHello = New Button()
                btnHello.Location = New Point(89, 12)
                btnHello.Name = "btnHello"
                btnHello.Size = New Size(105, 30)
                btnHello.Text = "Say Hello"
    
                ' Wire up an event handler to the button's "Click" event
                ' (see the code in the btnHello_Click function below).
                AddHandler btnHello.Click, New EventHandler(AddressOf btnHello_Click)
    
                ' Add the button to the form's control collection,
                ' so that it will appear on the form.
                Me.Controls.Add(btnHello)
            End Sub
    
            ' When the button is clicked, display a message.
            Private Sub btnHello_Click(sender As Object, e As EventArgs)
                MessageBox.Show("Hello, World!")
            End Sub
    
            ' This is the main entry point for the application.
            ' All VB.NET applications have one and only one of these methods.
            <STAThread> _
            Public Shared Sub Main()
                Application.EnableVisualStyles()
                Application.Run(New MainForm())
            End Sub
        End Class
    End Namespace
   

2. Save the file to a path you have read/write access to. It is conventional to name the file after the class that it contains—for example, X:\MainForm.vb.

3. Run the VB.NET compiler from the command line, passing the path to the code file as an argument:

    %WINDIR%\Microsoft.NET\Framework64\v4.0.30319\vbc.exe /target:winexe "X:\MainForm.vb"
   

   Note: To use a version of the VB.NET compiler for other .NET framework versions, take a look in the path %WINDIR%\Microsoft.NET and modify the example above accordingly. For more information on compiling VB.NET applications, see Hello World.

4. After compilation has completed, an application called MainForm.exe will be created in the same directory as your code file. You can run this application either from the command line or by double-clicking on it in Explorer.